Monday, November 08, 2010 at 12:05 AM.

---

system.verbs.builtins.radio.weblog.notify

on notify (adrblog) {
	<<Changes
		<<12/12/01; 7:37:24 PM by DW
			<<Log the ping.
		<<12/6/01; 7:38:05 PM by DW
			<<It was notifying only if upstreaming was enabled. I think this is bogus. Notification is independent of whether upstreaming is on or off. This has been one seriously confused routine. 
		<<11/9/01; 10:43:57 PM by DW
			<<Don't bother pinging Superhonker. It ain't listenin.
			<<fname wasn't being used. Goodbye.
			<<Reduced a hellacious piece of code to its native simplicity.
		<<11/8/01; 1:21:12 PM by JES
			<<Don't check adrblog^.prefs.ftp.enabled or adrblog^.prefs.manila.enabled, since these prefs no longer exist.
				<<FTP is integrated with upstreaming.
				<<Manila mirroring may be integrated with upstreaming at some point in the future.
		<<1/17/01; 12:13:48 PM by DW
			<<Created. Only do notification if they are FTPing. There isn't enough information stored (at this time) to reliably construct a url for the upstreamed weblog. Hmm maybe there is, here:
			<<user.playlist.data.upstream.files
			<<I'll probably figure it out later.
		<<2/1901 at 1:11:37 AM by JES
			<<Get the site URL by calling the bottleneck, radio.weblog.getUrl. Send notification for weblogs which are mirrored by ftp, manila, or upstream, but not for weblogs served from this copy of Radio.
		<<2/22/01; 9:45:26 PM by JES
			<<If this is a Mac, convert the title to Latin text
		<<9/27/01; 7:57:33 PM by JES
			<<Do update notification by calling weblogUpdates.ping, if system.verbs.apps.weblogUpdates is defined.
		<<9/28/01; 2:53:35 PM by JES
			<<Check the upstreaming pref at user.radio.prefs.upstream.enabled, instead of at user.playlist.data.upstream.enabled.
	if not tcp.isOffline () {
		local (title = adrblog^.prefs.title);
		if system.environment.isMac {
			title = latinToMac.macToLatin (title)};
		
		local (startticks = clock.ticks ());
		weblogUpdates.ping (title, radio.weblog.getUrl (adrblog));
		if user.radio.prefs.flLogWeblogsComPing {
			radio.log.add ("Weblogs", "Notified <a href=\"http://www.weblogs.com/\">Weblogs.Com</a> that your weblog has updated.", startticks)}}}
<<bundle //test code
	<<notify (radio.weblog.init ())

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.