Monday, November 08, 2010 at 12:05 AM.

---

system.verbs.builtins.radio.weblog.bloggerApi.checkUser

on checkUser (client, flpost, username, password) {
	<<Changes
		<<1/28/02; 7:54:54 PM by DW
			<<If the Blogger API is not enabled, deny access.
		<<1/22/02; 4:24:23 PM by DW
			<<Created.
	on deny () {
		scriptError ("Access denied.")};
	local (adrblog = radio.weblog.init ());
	if not adrblog^.prefs.flBloggerApiEnabled {
		deny ()};
	local (flSameMachine);
	bundle { //set flSameMachine
		if string.lower (client) == "localhost" {
			flSameMachine = true}
		else {
			if client == "127.0.0.1" {
				flSameMachine = true}
			else {
				try {flSameMachine = tcp.equalNames (client, tcp.myDottedID ())}}}};
	if flSameMachine {
		return (true)};
	if not user.radio.prefs.security.allowRemoteViewing {
		deny ()};
	if flpost {
		if not user.radio.prefs.security.allowRemotePost {
			deny ()}};
	if string.lower (username) != string.lower (user.radio.prefs.security.remoteUsername) {
		deny ()};
	if string (password) != string (user.radio.prefs.security.remotePassword) {
		deny ()}}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.