Monday, November 08, 2010 at 12:05 AM.

---

system.verbs.builtins.radio.utilities.readGlobalGlossary

<<Changes
	<<4/6/02; 6:57:22 PM by DW
		<<Rewrite.
		<<Only read the glossary if weblogData.shortcuts.prefs.flUserLandShortcuts is true.
		<<Instead of reading into user.html.glossary, read it into weblogData.shortcuts.userland and do a merge.
	<<12/1/01; 8:19:50 PM by DW
		<<I didn't have this script, so maybe other people didn't either. Checked out and checked it back in.
	<<9/13/01; 5:40:50 PM by JES
		<<Adapted to work with builtins.radio.
	<<2/4/01; 1:38:15 PM by DW
		<<Created. Reads the UserLand.Com glossary into user.html.glossary.

local (adrdata = radio.weblog.init ());
if adrdata^.shortcuts.prefs.flUserLandShortcuts {
	local (xstruct, startticks = clock.ticks ());
	xml.compile (tcp.httpReadUrl (user.radio.prefs.glossary.url), @xstruct);
	local (adrxgloss = xml.getAddress (@xstruct, "userLandGlobalGlossary"));
	local (adrxstruct = xml.getAddress (adrxgloss, "struct"));
	xml.coercions.structToFrontierValue (adrxstruct, @adrdata^.shortcuts.userland);
	radio.shortcuts.merge ();
	if user.radio.prefs.glossary.logging {
		radio.log.add ("Glossary read", sizeof (adrdata^.shortcuts.userland) + " items.", startticks)}}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.