Monday, November 08, 2010 at 12:05 AM.

---

system.verbs.builtins.radio.utilities.radio71FinishInstall

<<Changes
	<<12/9/01; 7:04:11 PM by JES
		<<Don't open the home page here. The user needs to swap in the new app first.
	<<12/9/01; 3:10:33 PM by JES
		<<Set radio.data.flReinstallHomeFolderFiles instead of radio.data.reinstallHomeFolderFiles.
	<<11/2/01; 1:55:13 PM by JES
		<<Only delete www/index.opml if www/index.txt also exists.
	<<10/9/01; 5:55:14 PM by JES
		<<Set radio.data.reinstallHomeFolderFiles to true, to cause the home folder text files to be installed.
	<<10/7/01; 8:43:10 PM by JES
		<<Fixed a bug where the myUserLand.root Tool, and myUserLandData.root Tool databases weren't properly uninstalled.
radio.init ();
bundle { //make sure the contents of the system folder is in synch with the odb
	radio.utilities.systemFolderTextFiles.install ()};
bundle { //make sure the contents of the home folder is in synch with the odb
	radio.data.flReinstallHomeFolderFiles = true;
	radio.utilities.homeFolderTextFiles.install ()};
bundle { //make sure the stories folder exists
	local (folder = user.radio.prefs.wwwfolder + "Stories" + file.getPathChar ());
	if not file.exists (folder) {
		file.newFolder (folder)}};
bundle { //delete index.opml if both index.txt and index.opml exist
	local (f = user.radio.prefs.wwwfolder + "index.opml");
	if file.exists (user.radio.prefs.wwwfolder + "index.txt") {
		if file.exists (f) {
			file.delete (f)}}};
bundle { //rebuild the menubar
	system.menus.buildMenuBar ()};
bundle { //replace the default responder
	user.webserver.responders.default.methods.any = radio.data.scripts.responderGlue};
bundle { //make sure the installer thread-agent is run right away
	radio.thread.agents.installer ()};
bundle { //uninstall MyUserLand.root and MyUserLandData.root
	radio.init ();
	radio.weblog.init ();
	if defined (user.tools.databases.MyUserLand) {
		user.tools.databases.MyUserLand.flEnabled = false};
	if defined (user.tools.databases.MyUserLandData) {
		user.tools.databases.MyUserLandData.flEnabled = false};
	Frontier.tools.checkTools ()}
<<bundle //open the home page
	<<local (portstring = "")
	<<if user.inetd.config.http.port != 80
		<<portstring = ":" + user.inetd.config.http.port
	<<radio.menuCommands.openPage ("http://127.0.0.1" + portstring + radio.data.systemUrls.setupRadio)

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.