Monday, November 08, 2010 at 12:05 AM.

---

system.verbs.builtins.radio.macros.emailConfig

<<Changes
	<<1/9/02; 1:42:22 AM by JES
		<<Localized the prompt for the "to" email address.
	<<12/15/01; 5:35:57 AM by JES
		<<Added a warning message when the user has not yet set their SMTP server. Made the error message more clear, if the user has not yet set their SMTP server.
	<<11/1/01; 6:03:11 PM by DW
		<<Created.

local (pta = html.getpagetableaddress ());
pta^.title = radio.string.getlocalizedstring ("emailconfig.title");
local (htmltext = "", indentlevel = 0);
on add (s) {
	htmltext = htmltext + string.filledstring ("\t", indentlevel) + s + "\r"};
add ("<p>" + radio.string.getlocalizedstring ("emailconfig.intro") + " " + radio.userinterface.helplink ("The Email Config page") + "</p>");
local (email = user.prefs.mailaddress);
bundle { //do the ping if args are present
	local (args);
	new (tabletype, @args);
	webserver.parseargs (pta^.searchargs, @args);
	if defined (args.email) {
		email = args.email;
		try {
			radio.utilities.mailUserLand (args.email);
			local (t);
			new (tabletype, @t);
			t.email = args.email;
			t.now = clock.now ();
			add ("<p><font color=\"#00008B\">" + radio.string.getlocalizedstring ("emailconfig.confirmation", @t) + "</font></p>")}
		else {
			if sizeOf (user.prefs.mailHost) == 0 {
				add (html.processMacros ("<p><font color=\"#8B0000\">" + radio.string.getlocalizedstring ("emailconfig.mailHostNotSetError") + "</font></p>"))}
			else {
				add ("<p><font color=\"#8B0000\">" + tryError + "</font></p>")}}}
	else {
		if sizeOf (user.prefs.mailHost) == 0 {
			add (html.processMacros ("<p>" + radio.string.getlocalizedstring ("emailconfig.mailHostNotSet") + "</p>"))}}};
add ("<form method=\"GET\">"); indentlevel++;
add ("<table cellspacing=\"10\" cellpadding=\"0\">"); indentlevel++;
add ("<tr><td>" + radio.string.getLocalizedString ("emailConfig.toAddressPrompt") + ": </td><td><input type=text size=\"50\" name=\"email\" value=\"" + email + "\"></td></tr>");
add ("<tr><td> </td><td><input type=\"submit\" value=\"" + radio.string.getlocalizedstring ("emailconfig.submit") + "\"></td></tr>");
add ("</table>"); indentlevel--;
add ("</form>"); indentlevel--;
return (htmltext)

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.