Monday, November 08, 2010 at 12:04 AM.

---

system.verbs.builtins.mainResponder.adminSite.prefs.securityLevel

on securityLevel (prompt) {
	<<Changes
		<<6/27/02; 7:59:04 PM by JES
			<<Created.
	local (pta = html.getPageTableAddress ());
	local (htmltext = "");
	on add (s) {
		htmltext = htmltext + (s + "\r");};
	
	if pta^.method == "POST" {
		local (adrargs = @pta^.postArgs);
		config.mainResponder.prefs.securityLevel = number (adrargs^.securityLevel)};
	
	add ("<tr>");
	add ("<td>" + prompt + ":</td>");
	
	local (levels = {"Basic Only", "Basic or Digest", "Digest Only", "Digest with replay protection"});
	add ("<td>");
	add ("<select name=\"securityLevel\">");
	local (i);
	for i = 0 to 3 {
		local (selectedtext = "");
		if i == config.mainResponder.prefs.securityLevel {
			selectedtext = " selected"};
		add ("<option value=\"" + i + "\"" + selectedtext + ">" + levels[i+1] + "</option>")};
	add ("</select>");
	add ("</td>");
	
	add ("</tr>");
	
	return (htmltext)}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.