Monday, November 08, 2010 at 12:01 AM.

---

system.verbs.apps.s3.simpleDb.getAllAttributes

on getAllAttributes (domain, itemName, adratts, adrerrorstring=nil) {
	<<Changes
		<<1/12/08; 9:26:19 AM by DW
			<<Created.
	local (t, xstruct);
	new (tabletype, @t);
	t.DomainName = domain;
	t.ItemName = itemName;
	new (tabletype, adratts);
	if s3.simpleDb.httpClient ("GetAttributes", @t, adrerrorstring, @xstruct) {
		local (adrresponse = xml.getaddress (@xstruct, "GetAttributesResponse"));
		local (adrresult = xml.getaddress (adrresponse, "GetAttributesResult"), adr);
		for adr in adrresult {
			if nameof (adr^) endswith "Attribute" {
				local (name = xml.getvalue (adr, "Name"));
				local (value = xml.getvalue (adr, "Value"));
				adratts^.[name] = value}};
		return (true)}
	else {
		return (false)}};
bundle { //test code
	if getAllAttributes ("flickrFanData", "Dave Winer", @scratchpad.atts) {
		edit (@scratchpad.atts)}}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.