Monday, November 08, 2010 at 12:00 AM.

---

scripting2Suite.server.savePrefs

on savePrefs (username, adrprefs) {
	<<Changes
		<<7/2/10; 6:16:35 AM by DW
			<<Created. 
	local (adrdata = scripting2suite.inituser (username), adrpref, flbuild = false);
	for adrpref in adrprefs {
		case string.lower (nameof (adrpref^)) {
			"headerimage" {
				wp.newtextobject (adrpref^, @adrdata^.prefs.headerimage);
				flbuild = true};
			"owneremail" {
				adrdata^.prefs.ownerEmail = adrpref^;
				flbuild = true};
			"ownername" {
				adrdata^.prefs.ownerName = adrpref^;
				flbuild = true};
			"weblogname" {
				adrdata^.prefs.weblogName = adrpref^;
				flbuild = true};
			"tagline" {
				adrdata^.prefs.tagline = adrpref^;
				flbuild = true};
			"timezone" {
				adrdata^.prefs.timezone = number (adrpref^);
				flbuild = true};
			"timezonename" {
				adrdata^.prefs.timezoneName = adrpref^;
				flbuild = true};
			"fldisquscomments" { //7/4/10 by DW
				adrdata^.prefs.flDisqusComments = adrpref^};
			"disqusshortname" { //7/4/10 by DW
				adrdata^.prefs.disqusShortName = adrpref^}}};
	new (tabletype, adrprefs); //empty out the table
	if flbuild {
		thread.callscript (@scripting2Suite.server.buildEverything, {username})};
	return (true)}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.