Monday, November 15, 2010 at 1:08 AM.

---

river2Suite.viewScan

on viewScan () {
	<<Changes
		<<11/14/10; 3:01:59 AM by DW
			<<If there's a "user" parameter on the request, pass it through to the index page when we redirect.
		<<6/22/09; 3:52:09 PM by DW
			<<Created. 
	local (pta = html.getpagetableaddress ());
	if pta^.method == "POST" {
		<<scratchpad.scanparams = pta^
		thread.callscript (@river2Suite.doScanNow, {});
		clock.waitseconds (1); //so there's a chance there are some new items on the home page
		bundle { //redirect, 11/14/10 by DW
			local (url = "index");
			if pta^.adruser != nil {
				url = url + "?user=" + nameof (pta^.adruser^)};
			webserver.redirect (pta, url)};
		return};
	local (htmltext = "", indentlevel = 0);
	on add (s) {
		htmltext = htmltext + string.filledstring ("\t", indentlevel) + s + "\r"};
	add ("<form method=\"POST\""); indentlevel++;
	add ("<br /><br />");
	add ("<h1>Click the \"Scan Now\" button to start a scan of all your feeds.</h1>");
	add ("<br /><br /><input id=\"submit\" type=\"submit\" name=\"scanButton\" class=\"submitButton\" value=\"Scan Now\" />");
	add ("</form>"); indentlevel--;
	return (htmltext)};
bundle { //test code
	viewScan ()}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.