Monday, November 08, 2010 at 12:00 AM.

---

river2Suite.initList

on initList (url) {
	<<Changes
		<<9/3/09; 3:45:51 AM by DW
			<<Init the listInfo table. 
		<<8/25/09; 1:36:44 PM by DW
			<<Init feeds sub-table.
		<<8/16/09; 11:06:09 AM by DW
			<<Created. 
	local (adrdata = river2suite.init ());
	local (adrlist = @adrdata^.lists.[url]);
	if not defined (adrlist^) {
		new (tabletype, adrlist)};
	bundle { //prefs
		if not defined (adrlist^.prefs) {
			new (tabletype, @adrlist^.prefs)};
		if not defined (adrlist^.prefs.enabled) {
			adrlist^.prefs.enabled = true}};
	bundle { //stats
		if not defined (adrlist^.stats) {
			new (tabletype, @adrlist^.stats)};
		if not defined (adrlist^.stats.ctReads) {
			adrlist^.stats.ctReads = 0};
		if not defined (adrlist^.stats.whenLastRead) {
			adrlist^.stats.whenLastRead = date (0)};
		if not defined (adrlist^.stats.whenSubscribed) {
			adrlist^.stats.whenSubscribed = timecreated (adrlist)}};
	bundle { //listInfo, 9/3/09 by DW
		if not defined (adrlist^.listInfo) {
			new (tabletype, @adrlist^.listInfo)};
		if not defined (adrlist^.listInfo.title) {
			adrlist^.listInfo.title = ""}};
	if not defined (adrlist^.feeds) {
		new (tabletype, @adrlist^.feeds)};
	if not defined (adrlist^.calendar) {
		new (tabletype, @adrlist^.calendar)};
	return (adrlist)};
bundle { //test code
	initList ("http://newsriver.org/podcastReadingList.opml")}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.