Monday, April 04, 2011 at 1:07 AM.

---

radio2Website.prefs

on prefs () {
	<<Changes
		<<3/10/11; 10:21:01 AM by DW
			<<Set activeUrls false. It was processing the text inside the templates. Not good. 
		<<3/9/11; 8:24:55 AM by DW
			<<If the user has one feed, then feedname must be the name of that feed. Makes sense, but that wasn't the way it was working. :-)
		<<3/8/11; 10:55:44 AM by DW
			<<Set the page title before returning. radio.prefs.browser sets it to " ". Not good for us. Also, send flShowNavigation param over to prefs browser, and set the page in the searchArgTable to 1.1. Very smooth effect for the users. 
		<<3/7/11; 10:06:47 AM by DW
			<<Update call to radio2Suite.securityChallenge to new conventions. 
		<<3/3/11; 3:01:09 PM by DW
			<<Establish a value for "feedname." This means we can edit the current feed's prefs this way. Pretty cool! :-)
	local (pta = html.getpagetableaddress (), adruser);
	scratchpad.prefsparams = pta^;
	if not radio2Suite.securityChallenge (@adruser) {
		return ("")};
	pta^.username = nameof (adruser^);
	bundle { //set pta^.feedname, 3/9/11 by DW
		pta^.feedname = adruser^.stats.lastFeedSelected;
		if sizeof (pta^.feedname) == 0 {
			pta^.feedname = nameof (adruser^.feeds [1])}};
	new (tabletype, @pta^.searchArgTable);
	webserver.parseargs (pta^.searchargs, @pta^.searchArgTable);
	pta^.searchArgTable.page = "1.1"; //3/8/11 by DW -- cough *hack* cough :-)
	if pta^.method == "POST" {
		new (tabletype, @pta^.postArgs);
		webserver.parseArgs (pta^.requestBody, @pta^.postArgs)};
	pta^.activeUrls = false; //3/10/11 by DW
	local (s =html.processmacros (radio.prefs.browser (@radio2Suite.data.prefsOutline, flShowNavigation:false)));
	pta^.title = "Preferences"; //3/8/11 by DW
	return (s)}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.