Saturday, April 02, 2011 at 9:17 PM.

---

feedhoseSuite.background.everyMinute

on everyMinute () {
	<<Changes
		<<12/2/10; 4:57:17 AM by DW
			<<Add call to feedhoseSuite.collectDeadThreads.
		<<9/24/10; 5:02:47 AM by DW
			<<Created. 
	local (adrdata = feedHoseSuite.init (), now = clock.now ());
	adrdata^.server.stats.ctEveryMinutes++;
	bundle { //init all the server hoses
		local (adrhose);
		for adrhose in @adrdata^.server.hoses {
			feedhoseSuite.initHose (nameof (adrhose^))}};
	<<if adrdata^.client.prefs.enabled
		<<local (fllaunch = false)
		<<if defined (system.temp.feedHose.client.idThread)
			<<fllaunch = not thread.exists (system.temp.feedHose.client.idThread)
		<<else
			<<fllaunch = true
		<<if fllaunch
			<<thread.callscript (@feedhoseSuite.client.main, {})
	if adrdata^.client.prefs.enabled {
		local (adrhose);
		for adrhose in @adrdata^.client.hoses {
			local (hosename = nameof (adrhose^), fllaunch);
			feedhoseSuite.client.initHose (hosename);
			if adrhose^.prefs.enabled {
				bundle { //set fllaunch
					local (adrid = @system.temp.feedHose.client.threadIDs.[hosename]);
					if defined (adrid^) {
						fllaunch = not thread.exists (adrid^)}
					else {
						fllaunch = true}};
				if fllaunch {
					thread.callscript (@feedhoseSuite.client.main, {hosename});
					adrhose^.stats.ctLaunches++;
					adrhose^.stats.whenLastLaunch = clock.now ()};
				if adrhose^.stats.flWrite {
					feedhoseSuite.client.write (hosename);
					adrhose^.stats.flWrite = false}}}};
	feedhoseSuite.collectOldTitles ();
	feedhoseSuite.collectDeadThreads ()}; //12/2/10 by DW
bundle { //test code
	everyMinute ()}

---

This listing is for code that runs in the OPML Editor environment. I created these listings because I wanted the search engines to index it, so that when I want to look up something in my codebase I don't have to use the much slower search functionality in my object database. Dave Winer.